flake parts

modules/hosts/darwin.nix

@@ -0,0 +1,33 @@
+{
+  hosts,
+  inputs,
+  username,
+  mkSpecialArgs,
+  mkHomeManagerModule,
+  ...
+}:
+let
+  host = hosts.darwin;
+in
+{
+  flake.darwinConfigurations.${host.name} = inputs.nix-darwin.lib.darwinSystem {
+    system = host.system;
+    specialArgs = mkSpecialArgs host;
+    modules = [
+      ../../hosts/${host.name}
+      inputs.home-manager.darwinModules.home-manager
+      inputs.nix-homebrew.darwinModules.nix-homebrew
+      {
+        users.users.${username}.home = host.homeDirectory;
+
+        nix-homebrew = {
+          enable = true;
+          enableRosetta = true;
+          user = username;
+          autoMigrate = true;
+        };
+      }
+      (mkHomeManagerModule host)
+    ];
+  };
+}

modules/hosts/netty.nix

@@ -0,0 +1,33 @@
+{
+  hosts,
+  inputs,
+  mkPkgs,
+  mkSpecialArgs,
+  mkHomeManagerModule,
+  ...
+}:
+let
+  host = hosts.netty;
+in
+{
+  flake = {
+    nixosConfigurations.${host.name} = inputs.nixpkgs.lib.nixosSystem {
+      system = host.system;
+      specialArgs = mkSpecialArgs host;
+      modules = [
+        inputs.disko.nixosModules.disko
+        ../../hosts/${host.name}/configuration.nix
+        inputs.home-manager.nixosModules.home-manager
+        (mkHomeManagerModule host)
+      ];
+    };
+
+    homeConfigurations.${host.name} = inputs.home-manager.lib.homeManagerConfiguration {
+      pkgs = mkPkgs host.system;
+      extraSpecialArgs = mkSpecialArgs host;
+      modules = [
+        host.standaloneHomeModule
+      ];
+    };
+  };
+}

modules/nixpkgs.nix

@@ -0,0 +1,45 @@
+{
+  self,
+  inputs,
+  lib,
+  ...
+}:
+let
+  username = "rathi";
+  hosts = import ../lib/hosts.nix { inherit username; };
+
+  mkPkgs =
+    system:
+    import inputs.nixpkgs {
+      inherit system;
+      config.allowUnfree = true;
+    };
+
+  mkSpecialArgs = host: {
+    inherit inputs self username;
+    hostname = host.hostname;
+  };
+
+  mkHomeManagerModule =
+    host:
+    {
+      home-manager.useGlobalPkgs = true;
+      home-manager.useUserPackages = true;
+      home-manager.extraSpecialArgs = mkSpecialArgs host;
+      home-manager.backupCommand = "bash ${../scripts/home-manager-backup.sh}";
+      home-manager.users.${username} = import host.homeModule;
+    };
+in
+{
+  systems = lib.unique (map (host: host.system) (builtins.attrValues hosts));
+
+  _module.args = {
+    inherit
+      username
+      hosts
+      mkPkgs
+      mkSpecialArgs
+      mkHomeManagerModule
+      ;
+  };
+}